BCX_BITMAP function
Purpose:
BCX_BITMAP creates a static control then loads a
bitmap from a file and displays the bitmap on the static
control.
Syntax:
hCtl = BCX_BITMAP(BitmapFile AS STRING, _
hwndParent AS HWND, _
CtlID AS INTEGER, _
Xpos AS INTEGER, _
Ypos AS INTEGER, _
Width AS INTEGER, _
Height AS INTEGER _
[, Res AS INTEGER] _
[, WinStyle AS INTEGER] _
[, ExWinStyle AS INTEGER])
Return Value:
- Data type: HWND
hCtl The handle of the static control
containing the bitmap, if the control was created. If the function
fails, the return value is NULL.
👉 The returned handle, hCtl, is not a handle of the bitmap; it is to the static
control containing the bitmap.
Parameters:
- Data type: STRING
BitmapFile The file containing bitmap to be
loaded. If the bitmap is to be loaded from a resource then this
parameter must be empty ("").
👉 If a NULL image pointer, (""), is
specified without specifying a value for the Res parameter, a HWND control
will be returned from the function but with no immediate image
being displayed.
- Data type: HWND
hwndParent The handle of the window on which
the control-bitmap will be placed.
- Data type: INTEGER
CtlID The child-window identifier used to
notify its parent about events.
- Data type: INTEGER
Xpos The horizontal placement of upper left
corner of the control-bitmap
- Data type: INTEGER
Ypos The vertical placement of upper left
corner of the control-bitmap
- Data type: INTEGER
Width Sets the width of displayed bitmap.
BCX_BITMAP will autosize the bitmap to the size of
the control if the Width and Height parameters are both zero.
- Data type: INTEGER
Height Sets the height of displayed bitmap.
BCX_BITMAP will autosize the bitmap to the size of
the control if the Width and Height parameters are both zero.
- Data type: INTEGER
Res [OPTIONAL] The
bitmap resource identifier, used if the bitmap is to be retrieved
as a resource.
- Data type: INTEGER
WinStyle [OPTIONAL]
If the WinStyle parameter is used, the
default Window Style for a BCX_BITMAP
control, WS_CHILD | WS_VISIBLE | SS_BITMAP | WS_TABSTOP, is
replaced with the value in WinStyle. For
more information, visit the Microsoft Static Control Styles webpage and the
Microsoft Window Styles webpage
- Data type: INTEGER
ExWinStyle [OPTIONAL] The default window Extended Window Style for
a BCX_BITMAP control is 0. For more information, visit
the Microsoft Extended Window Styles webpage.
|
Remarks:
An image can be set into such a control at runtime using the
SET_BCX_BITMAP2 function.
Example:
Save the example code below as bcx_bitmap.bas. The example will
load, into a window, from a resource file, this bitmap:
Click here to download a
.zip containing the bcx_bitmap.bmp resource.
Extract it to the same directory as bcx_bitmap.bas.
Save the following batch file, as Build.bat, into the same
directory as bcx_bitmap.bas and run Build.bat to compile and run
the example.
Build.bat Compilation Batch file:
CALL povars64.bat
bc bcx_bitmap
bcx_bitmap.bas
GUI "BCX_BITMAP"
$IPRINT_OFF
$RESOURCE "$PELLES$\bin\porc.exe"
$COMPILER "$PELLES$\Bin\pocc -W1 -Gd -Go -Ze -Zx -Tx64-coff $FILE$.c"
$LINKER "$PELLES$\Bin\polink _
-release _
-machine:X64 _
-subsystem:windows _
-OUT:$FILE$.exe _
$FILE$.obj _
$FILE$__.res"
$ONEXIT "$FILE$.exe"
BCX_RESOURCE 500 BITMAP "bcx_bitmap.bmp"
SUB FORMLOAD
GLOBAL Form1 AS HWND
GLOBAL Bmp1 AS CONTROL
Form1 = BCX_FORM("BCX_BITMAP", 0, 0, 130, 115)
BCX_SET_FORM_COLOR(Form1,QBCOLOR(15))
Bmp1 = BCX_BITMAP("", Form1, 115, 10, 10, 0, 0, 500)
CENTER(Form1)
SHOW(Form1)
END SUB
BEGIN EVENTS
SELECT CASE CBMSG
CASE WM_CLOSE
IF MSGBOX("Are you sure?", "Quit Program?", MB_YESNO) = IDYES THEN
DestroyWindow(Form1)
END IF
EXIT FUNCTION
END SELECT
END EVENTS
Remarks:
The default window Style for a BCX_BITMAP
control also can be changed by using the MODSTYLE
function.
For an example of the BCX_BITMAP
function see Demo.bas.
SET_BCX_BITMAP statement
Purpose:
SET_BCX_BITMAP complements the BCX_BITMAP
function by allowing the bitmap image of a BCX_BITMAP
control to be changed after the control has been created.
Syntax:
SET_BCX_BITMAP(hBitmapDest AS HWND, _
BitmapFile AS STRING _
[, Res AS INTEGER] _
[, Width AS INTEGER] _
[, Height AS INTEGER])
Parameters:
- Data type: HWND
hBitmapDest The handle of the control,
created by BCX_BITMAP, onto which the bitmap is to be set.
- Data type: STRING
BitmapFile The filename of bitmap to be
placed on the control. This parameter is set to "" if the bitmap is
to be retrieved from a resource.
- Data type: INTEGER
Res [OPTIONAL] The
bitmap resource identifier used if the bitmap is to be retrieved
from a resource.
- Data type: INTEGER
Width [OPTIONAL] The
width to which the bitmap is to be set.
- Data type: INTEGER
Height [OPTIONAL]
The height to which the bitmap is to be set.
|
Remarks:
The SET_BCX_BITMAP statement has been written so that
either a file based bitmap or a resource based bitmap can be passed
to the procedure. The default setting for the optional parameter
Res is 0 which means that the bitmap will be
retrieved from the file specified in BitmapFile. If the bitmap is to be retrieved from a
resource then the integer value of the bitmap resource handle is
passed in Res and 0 is used as a parameter
value for BitmapFile.
An example demonstrating the use of the SET_BCX_BITMAP is available in the Setbmp directory
of the GUI_Demo.zip, downloadable from the BCX BASIC Forum post
GUI Demos 2020 at https://bcxbasiccoders.com/smf/index.php?topic=390.0